CMakeLists.txt 38 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586878889909192939495969798991001011021031041051061071081091101111121131141151161171181191201211221231241251261271281291301311321331341351361371381391401411421431441451461471481491501511521531541551561571581591601611621631641651661671681691701711721731741751761771781791801811821831841851861871881891901911921931941951961971981992002012022032042052062072082092102112122132142152162172182192202212222232242252262272282292302312322332342352362372382392402412422432442452462472482492502512522532542552562572582592602612622632642652662672682692702712722732742752762772782792802812822832842852862872882892902912922932942952962972982993003013023033043053063073083093103113123133143153163173183193203213223233243253263273283293303313323333343353363373383393403413423433443453463473483493503513523533543553563573583593603613623633643653663673683693703713723733743753763773783793803813823833843853863873883893903913923933943953963973983994004014024034044054064074084094104114124134144154164174184194204214224234244254264274284294304314324334344354364374384394404414424434444454464474484494504514524534544554564574584594604614624634644654664674684694704714724734744754764774784794804814824834844854864874884894904914924934944954964974984995005015025035045055065075085095105115125135145155165175185195205215225235245255265275285295305315325335345355365375385395405415425435445455465475485495505515525535545555565575585595605615625635645655665675685695705715725735745755765775785795805815825835845855865875885895905915925935945955965975985996006016026036046056066076086096106116126136146156166176186196206216226236246256266276286296306316326336346356366376386396406416426436446456466476486496506516526536546556566576586596606616626636646656666676686696706716726736746756766776786796806816826836846856866876886896906916926936946956966976986997007017027037047057067077087097107117127137147157167177187197207217227237247257267277287297307317327337347357367377387397407417427437447457467477487497507517527537547557567577587597607617627637647657667677687697707717727737747757767777787797807817827837847857867877887897907917927937947957967977987998008018028038048058068078088098108118128138148158168178188198208218228238248258268278288298308318328338348358368378388398408418428438448458468478488498508518528538548558568578588598608618628638648658668678688698708718728738748758768778788798808818828838848858868878888898908918928938948958968978988999009019029039049059069079089099109119129139149159169179189199209219229239249259269279289299309319329339349359369379389399409419429439449459469479489499509519529539549559569579589599609619629639649659669679689699709719729739749759769779789799809819829839849859869879889899909919929939949959969979989991000100110021003100410051006
  1. ###########################################################################
  2. #
  3. # Library: CTK
  4. #
  5. # Copyright (c) Kitware Inc.
  6. #
  7. # Licensed under the Apache License, Version 2.0 (the "License");
  8. # you may not use this file except in compliance with the License.
  9. # You may obtain a copy of the License at
  10. #
  11. # http://www.apache.org/licenses/LICENSE-2.0.txt
  12. #
  13. # Unless required by applicable law or agreed to in writing, software
  14. # distributed under the License is distributed on an "AS IS" BASIS,
  15. # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16. # See the License for the specific language governing permissions and
  17. # limitations under the License.
  18. #
  19. ###########################################################################
  20. cmake_minimum_required(VERSION 2.8.4)
  21. #-----------------------------------------------------------------------------
  22. # See http://cmake.org/cmake/help/cmake-2-8-docs.html#section_Policies for details
  23. #
  24. set(project_policies
  25. CMP0001 # NEW: CMAKE_BACKWARDS_COMPATIBILITY should no longer be used.
  26. CMP0002 # NEW: Logical target names must be globally unique.
  27. CMP0003 # NEW: Libraries linked via full path no longer produce linker search paths.
  28. CMP0004 # NEW: Libraries linked may NOT have leading or trailing whitespace.
  29. CMP0005 # NEW: Preprocessor definition values are now escaped automatically.
  30. CMP0006 # NEW: Installing MACOSX_BUNDLE targets requires a BUNDLE DESTINATION.
  31. CMP0007 # NEW: List command no longer ignores empty elements.
  32. CMP0008 # NEW: Libraries linked by full-path must have a valid library file name.
  33. CMP0009 # NEW: FILE GLOB_RECURSE calls should not follow symlinks by default.
  34. CMP0010 # NEW: Bad variable reference syntax is an error.
  35. CMP0011 # NEW: Included scripts do automatic cmake_policy PUSH and POP.
  36. CMP0012 # NEW: if() recognizes numbers and boolean constants.
  37. CMP0013 # NEW: Duplicate binary directories are not allowed.
  38. CMP0014 # NEW: Input directories must have CMakeLists.txt
  39. )
  40. foreach(policy ${project_policies})
  41. if(POLICY ${policy})
  42. cmake_policy(SET ${policy} NEW)
  43. endif()
  44. endforeach()
  45. #-----------------------------------------------------------------------------
  46. if(APPLE)
  47. # Note: By setting CMAKE_OSX_* variables before any enable_language() or project() calls,
  48. # we ensure that the bitness will be properly detected.
  49. include(${CMAKE_SOURCE_DIR}/CMake/ctkBlockSetCMakeOSXVariables.cmake)
  50. endif()
  51. #-----------------------------------------------------------------------------
  52. project(CTK)
  53. #-----------------------------------------------------------------------------
  54. #-----------------------------------------------------------------------------
  55. # Library mode: SHARED (default) or STATIC
  56. #
  57. set(CTK_LIBRARY_MODE "SHARED")
  58. option(CTK_BUILD_SHARED_LIBS "Build CTK libraries as shared module." ON)
  59. mark_as_advanced(CTK_BUILD_SHARED_LIBS)
  60. if(NOT CTK_BUILD_SHARED_LIBS)
  61. set(CTK_LIBRARY_MODE "STATIC")
  62. endif()
  63. #-----------------------------------------------------------------------------
  64. # Set a default build type if none was specified
  65. #
  66. if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  67. message(STATUS "Setting build type to 'Debug' as none was specified.")
  68. set(CMAKE_BUILD_TYPE Debug CACHE STRING "Choose the type of build." FORCE)
  69. mark_as_advanced(CMAKE_BUILD_TYPE)
  70. # Set the possible values of build type for cmake-gui
  71. set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72. "MinSizeRel" "RelWithDebInfo")
  73. endif()
  74. #-----------------------------------------------------------------------------
  75. # Superbuild Option - Enabled by default
  76. #
  77. option(CTK_SUPERBUILD "Build CTK and the projects it depends on via SuperBuild.cmake." ON)
  78. mark_as_advanced(CTK_SUPERBUILD)
  79. #-----------------------------------------------------------------------------
  80. # Output directories.
  81. #
  82. foreach(type LIBRARY RUNTIME ARCHIVE)
  83. # Make sure the directory exists
  84. if(DEFINED CTK_CMAKE_${type}_OUTPUT_DIRECTORY
  85. AND NOT EXISTS ${CTK_CMAKE_${type}_OUTPUT_DIRECTORY})
  86. message(FATAL_ERROR "CTK_CMAKE_${type}_OUTPUT_DIRECTORY is set to a non-existing directory [${CTK_CMAKE_${type}_OUTPUT_DIRECTORY}]")
  87. endif()
  88. if(CTK_SUPERBUILD)
  89. set(output_dir ${CTK_BINARY_DIR}/bin)
  90. if(NOT DEFINED CTK_CMAKE_${type}_OUTPUT_DIRECTORY)
  91. set(CTK_CMAKE_${type}_OUTPUT_DIRECTORY ${CTK_BINARY_DIR}/CTK-build/bin)
  92. endif()
  93. else()
  94. if(NOT DEFINED CTK_CMAKE_${type}_OUTPUT_DIRECTORY)
  95. set(output_dir ${CTK_BINARY_DIR}/bin)
  96. else()
  97. set(output_dir ${CTK_CMAKE_${type}_OUTPUT_DIRECTORY})
  98. endif()
  99. endif()
  100. set(CMAKE_${type}_OUTPUT_DIRECTORY ${output_dir} CACHE INTERNAL "Single output directory for building all libraries.")
  101. if(NOT DEFINED CTK_PLUGIN_${type}_OUTPUT_DIRECTORY)
  102. set(CTK_PLUGIN_${type}_OUTPUT_DIRECTORY ${CMAKE_${type}_OUTPUT_DIRECTORY})
  103. endif()
  104. endforeach()
  105. #-----------------------------------------------------------------------------
  106. # CTK version number. An even minor number corresponds to releases.
  107. #
  108. set(CTK_MAJOR_VERSION 0)
  109. set(CTK_MINOR_VERSION 1)
  110. set(CTK_PATCH_VERSION 0)
  111. set(CTK_VERSION
  112. "${CTK_MAJOR_VERSION}.${CTK_MINOR_VERSION}.${CTK_PATCH_VERSION}")
  113. # Append the library version information to the library target
  114. # properties. A parent project may set its own properties and/or may
  115. # block this.
  116. if(NOT CTK_NO_LIBRARY_VERSION)
  117. set(CTK_LIBRARY_PROPERTIES ${CTK_LIBRARY_PROPERTIES}
  118. VERSION "${CTK_VERSION}"
  119. SOVERSION "${CTK_MAJOR_VERSION}.${CTK_MINOR_VERSION}"
  120. )
  121. endif()
  122. #-----------------------------------------------------------------------------
  123. # Install directories, used for install rules.
  124. #
  125. if(NOT CTK_INSTALL_BIN_DIR)
  126. set(CTK_INSTALL_BIN_DIR "bin")
  127. endif()
  128. if(NOT CTK_INSTALL_LIB_DIR)
  129. set(CTK_INSTALL_LIB_DIR "lib/ctk-${CTK_MAJOR_VERSION}.${CTK_MINOR_VERSION}")
  130. endif()
  131. if(NOT CTK_INSTALL_INCLUDE_DIR)
  132. set(CTK_INSTALL_INCLUDE_DIR "include/ctk-${CTK_MAJOR_VERSION}.${CTK_MINOR_VERSION}")
  133. endif()
  134. if(NOT CTK_INSTALL_DOC_DIR)
  135. set(CTK_INSTALL_DOC_DIR "doc")
  136. endif()
  137. #-----------------------------------------------------------------------------
  138. # Update CMake module path
  139. # Note: FindXXX.cmake script specific to utility should be copied into Utilities/CMake
  140. #
  141. set(CMAKE_MODULE_PATH
  142. "${CMAKE_CURRENT_SOURCE_DIR}/Utilities/CMake"
  143. "${CMAKE_CURRENT_SOURCE_DIR}/CMake"
  144. ${CMAKE_MODULE_PATH})
  145. #-----------------------------------------------------------------------------
  146. # Clear CTK_BASE_INCLUDE_DIRS, CTK_BASE_LIBRARIES and CTK_WRAPPED_LIBRARIES_PYTHONQT
  147. #
  148. set(CTK_BASE_LIBRARIES CACHE INTERNAL "CTK base libraries" FORCE)
  149. set(CTK_BASE_INCLUDE_DIRS CACHE INTERNAL "CTK includes" FORCE)
  150. set(CTK_WRAPPED_LIBRARIES_PYTHONQT CACHE INTERNAL "CTK libraries wrapped using PythonQt" FORCE)
  151. # Variable use in CTKConfig.cmake.in
  152. set(CTK_LIBRARIES CACHE INTERNAL "CTK libraries" FORCE)
  153. set(${PROJECT_NAME}_PLUGIN_LIBRARIES CACHE INTERNAL "CTK plugins" FORCE)
  154. # Used by CTKGenerateCTKConfig.cmake and also used to reference script from other scripts
  155. set(CTK_CMAKE_DIR ${CTK_SOURCE_DIR}/CMake)
  156. set(CTK_CMAKE_UTILITIES_DIR ${CTK_SOURCE_DIR}/Utilities/CMake)
  157. #-----------------------------------------------------------------------------
  158. # CMake function(s) and macro(s)
  159. #
  160. include(CMake/ctkMacroParseArguments.cmake)
  161. include(CMake/ctkMacroSetPaths.cmake)
  162. include(CMake/ctkMacroListFilter.cmake)
  163. include(CMake/ctkMacroOptionUtils.cmake)
  164. include(CMake/ctkMacroBuildLib.cmake)
  165. include(CMake/ctkMacroBuildLibWrapper.cmake)
  166. include(CMake/ctkMacroBuildPlugin.cmake)
  167. include(CMake/ctkMacroBuildApp.cmake)
  168. include(CMake/ctkMacroBuildQtPlugin.cmake)
  169. include(CMake/ctkMacroCompilePythonScript.cmake)
  170. include(CMake/ctkMacroGenerateMocs.cmake)
  171. include(CMake/ctkMacroWrapPythonQt.cmake)
  172. include(CMake/ctkMacroSetupQt.cmake)
  173. include(CMake/ctkMacroTargetLibraries.cmake) # Import multiple macros
  174. include(CMake/ctkFunctionExtractOptionNameAndValue.cmake)
  175. include(CMake/ctkMacroValidateBuildOptions.cmake)
  176. include(CMake/ctkMacroAddCtkLibraryOptions.cmake)
  177. include(CMake/ctkFunctionGenerateDGraphInput.cmake)
  178. include(CMake/ctkFunctionGenerateProjectXml.cmake)
  179. include(CMake/ctkFunctionGeneratePluginManifest.cmake)
  180. include(CMake/ctkMacroGeneratePluginResourceFile.cmake)
  181. include(CMake/ctkFunctionAddPluginRepo.cmake)
  182. include(CMake/ctkFunctionCheckCompilerFlags.cmake)
  183. include(CMake/ctkFunctionCheckoutRepo.cmake)
  184. include(CMake/ctkFunctionGetIncludeDirs.cmake)
  185. include(CMake/ctkFunctionGetLibraryDirs.cmake)
  186. include(CMake/ctkFunctionGetGccVersion.cmake)
  187. include(CMake/ctkFunctionGetCompilerVisibilityFlags.cmake)
  188. include(CMake/ctkFunctionCompileSnippets.cmake)
  189. #-----------------------------------------------------------------------------
  190. # Testing
  191. #
  192. include(CTest)
  193. mark_as_advanced(BUILD_TESTING)
  194. if(BUILD_TESTING)
  195. set(CPP_TEST_PATH ${CMAKE_RUNTIME_OUTPUT_DIRECTORY})
  196. mark_as_advanced(TCL_TCLSH DART_ROOT)
  197. include(CMake/ctkMacroSimpleTest.cmake)
  198. include(CMake/ctkMacroSimpleTestWithData.cmake)
  199. # Setup file for setting custom ctest vars
  200. configure_file(
  201. CMake/CTestCustom.cmake.in
  202. ${CMAKE_CURRENT_BINARY_DIR}/CTestCustom.cmake
  203. @ONLY
  204. )
  205. # Configuration for the CMake-generated test driver
  206. set(CMAKE_TESTDRIVER_EXTRA_INCLUDES "#include <stdexcept>")
  207. set(CMAKE_TESTDRIVER_BEFORE_TESTMAIN "
  208. try
  209. {")
  210. set(CMAKE_TESTDRIVER_AFTER_TESTMAIN " }
  211. catch( std::exception & excp )
  212. {
  213. fprintf(stderr,\"%s\\n\",excp.what());
  214. return EXIT_FAILURE;
  215. }
  216. catch( ... )
  217. {
  218. printf(\"Exception caught in the test driver\\n\");
  219. return EXIT_FAILURE;
  220. }
  221. ")
  222. endif()
  223. #-----------------------------------------------------------------------------
  224. # QtTesting
  225. #
  226. option(CTK_USE_QTTESTING "Enable/Disable QtTesting" OFF)
  227. mark_as_advanced(CTK_USE_QTTESTING)
  228. #-----------------------------------------------------------------------------
  229. # Coverage
  230. #
  231. option(WITH_COVERAGE "Enable/Disable coverage" OFF)
  232. mark_as_advanced(WITH_COVERAGE)
  233. #-----------------------------------------------------------------------------
  234. # Documentation
  235. #
  236. option(DOCUMENTATION_TARGET_IN_ALL "Include the custom target for building documentation in 'all'" OFF)
  237. mark_as_advanced(DOCUMENTATION_TARGET_IN_ALL)
  238. set(DOCUMENTATION_ARCHIVES_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  239. CACHE PATH "Where documentation archives should be stored")
  240. mark_as_advanced(DOCUMENTATION_ARCHIVES_OUTPUT_DIRECTORY)
  241. #-----------------------------------------------------------------------------
  242. # Additional CXX/C Flags
  243. #
  244. set(ADDITIONAL_C_FLAGS "" CACHE STRING "Additional C Flags")
  245. mark_as_advanced(ADDITIONAL_C_FLAGS)
  246. set(ADDITIONAL_CXX_FLAGS "" CACHE STRING "Additional CXX Flags")
  247. mark_as_advanced(ADDITIONAL_CXX_FLAGS)
  248. #-----------------------------------------------------------------------------
  249. # Set symbol visibility Flags
  250. #
  251. ctkFunctionGetCompilerVisibilityFlags(VISIBILITY_CXX_FLAGS)
  252. #-----------------------------------------------------------------------------
  253. # Set coverage Flags
  254. #
  255. if(WITH_COVERAGE)
  256. if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
  257. set(coverage_flags "-g -fprofile-arcs -ftest-coverage -O0 -DNDEBUG")
  258. set(COVERAGE_CXX_FLAGS ${coverage_flags})
  259. set(COVERAGE_C_FLAGS ${coverage_flags})
  260. endif()
  261. endif()
  262. #-----------------------------------------------------------------------------
  263. # CTK C/CXX Flags
  264. #
  265. set(CTK_C_FLAGS "${CMAKE_C_FLAGS_INIT} ${COVERAGE_C_FLAGS} ${ADDITIONAL_C_FLAGS}")
  266. set(CTK_CXX_FLAGS "${CMAKE_CXX_FLAGS_INIT} ${VISIBILITY_CXX_FLAGS} ${COVERAGE_CXX_FLAGS} ${ADDITIONAL_CXX_FLAGS}")
  267. if(CMAKE_COMPILER_IS_GNUCXX)
  268. set(cflags "-Wall -Wextra -Wpointer-arith -Winvalid-pch -Wcast-align -Wwrite-strings -D_FORTIFY_SOURCE=2")
  269. ctkFunctionCheckCompilerFlags("-fdiagnostics-show-option" cflags)
  270. ctkFunctionCheckCompilerFlags("-Wl,--no-undefined" cflags)
  271. ctkFunctionGetGccVersion(${CMAKE_CXX_COMPILER} GCC_VERSION)
  272. # With older version of gcc supporting the flag -fstack-protector-all, an extra dependency to libssp.so
  273. # is introduced. If gcc is smaller than 4.4.0 and the build type is Release let's not include the flag.
  274. # Doing so should allow to build package made for distribution using older linux distro.
  275. if(${GCC_VERSION} VERSION_GREATER "4.4.0" OR (CMAKE_BUILD_TYPE STREQUAL "Debug" AND ${GCC_VERSION} VERSION_LESS "4.4.0"))
  276. ctkFunctionCheckCompilerFlags("-fstack-protector-all" cflags)
  277. endif()
  278. if(MINGW)
  279. # suppress warnings about auto imported symbols
  280. set(CTK_CXX_FLAGS "-Wl,--enable-auto-import ${CTK_CXX_FLAGS}")
  281. endif()
  282. set(CTK_C_FLAGS "${cflags} ${CTK_C_FLAGS}")
  283. set(CTK_CXX_FLAGS "${cflags} -Woverloaded-virtual -Wold-style-cast -Wstrict-null-sentinel -Wsign-promo ${CTK_CXX_FLAGS}")
  284. endif()
  285. if(MSVC)
  286. set(msvc_suppressed_warnings
  287. "/wd4290" # C++ exception specification ignored except to indicate a function is not __declspec(nothrow)
  288. )
  289. set(CTK_CXX_FLAGS "${CTK_CXX_FLAGS} ${msvc_suppressed_warnings}")
  290. endif()
  291. #-----------------------------------------------------------------------------
  292. # QT
  293. #
  294. ctkMacroSetupQt()
  295. # Update CTK_BASE_LIBRARIES with QT libraries
  296. if(QT4_FOUND)
  297. set(CTK_BASE_LIBRARIES ${CTK_BASE_LIBRARIES} ${QT_LIBRARIES} CACHE INTERNAL "CTK base libraries" FORCE)
  298. endif()
  299. #-----------------------------------------------------------------------------
  300. # To make options show up in both CTK-SuperBuild and CTK regular build, let's add them
  301. # before the SuperBuild script is included
  302. #
  303. #-----------------------------------------------------------------------------
  304. # High-Level CTK options
  305. # The ctk_enable_option macro expects a logical expression after the first
  306. # three arguments. This expression should only contain build option names
  307. # which belong to leafs in the required dependency tree.
  308. # The CTK infrastructure for high-level DICOM support. This includes
  309. # DICOM indexing, networking, and GUI widgets.
  310. ctk_enable_option(DICOM "Enable default DICOM support" OFF
  311. CTK_LIB_DICOM/Widgets)
  312. # The CTK infrastructure for building a DICOM Part 19 compliant application
  313. # host and/or hosted application. This will not enable any example plugins
  314. # or executables (enable CTK_ENABLE_EXAMPLES for that).
  315. ctk_enable_option(DICOMApplicationHosting "Enable DICOM Part 19 Application Hosting support" OFF
  316. CTK_PLUGIN_org.commontk.dah.host AND CTK_PLUGIN_org.commontk.dah.hostedapp)
  317. # The CTK Qt Widgets. This will enable the Qt Widget library only.
  318. # It might trigger the enabling of other widget libraries in combination
  319. # with other enabled options.
  320. ctk_enable_option(Widgets "Enable Qt Widget libraries" OFF
  321. CTK_LIB_Widgets)
  322. # The CTK Plugin Framework, a dynamic component system based on OSGi.
  323. # This will enable only the framework itself.
  324. ctk_enable_option(PluginFramework "Enable Plugin Framework" OFF
  325. CTK_LIB_PluginFramework)
  326. #-----------------------------------------------------------------------------
  327. # Special "BUILD ALL" options
  328. # Build all CTK plug-ins
  329. option(CTK_BUILD_ALL_PLUGINS "Build all CTK plug-ins" OFF)
  330. # Build all CTK libraries
  331. option(CTK_BUILD_ALL_LIBRARIES "Build all CTK libraries" OFF)
  332. # Build all CTK applications
  333. option(CTK_BUILD_ALL_APPS "Build all CTK applications" OFF)
  334. # Build everything
  335. option(CTK_BUILD_ALL "Build everything in CTK" OFF)
  336. if(CTK_BUILD_ALL)
  337. set(CTK_BUILD_ALL_PLUGINS 1)
  338. set(CTK_BUILD_ALL_LIBRARIES 1)
  339. set(CTK_BUILD_ALL_APPS 1)
  340. endif()
  341. #-----------------------------------------------------------------------------
  342. # Other options
  343. # The CTK Python Wrapping
  344. ctk_enable_option(Python_Wrapping "Wrap CTK classes using Qt meta-object system into Python language" OFF
  345. CTK_LIB_Scripting/Python/Core)
  346. # Build examples
  347. # Create the logical expression containing the minium set of required options
  348. # for the CTK_BUILD_EXAMPLES option to be ON
  349. set(_build_examples_logical_expr)
  350. foreach(_app ${CTK_ENABLED_APPS})
  351. list(APPEND _build_examples_logical_expr CTK_APP_${_app} AND)
  352. endforeach()
  353. if(_build_examples_logical_expr)
  354. list(REMOVE_AT _build_examples_logical_expr -1)
  355. endif()
  356. ctk_enable_option_raw(CTK_BUILD_EXAMPLES "Build examples for CTK components" OFF
  357. ${_build_examples_logical_expr})
  358. # Git protocol option
  359. option(CTK_USE_GIT_PROTOCOL "If behind a firewall turn this OFF to use http instead." ON)
  360. mark_as_advanced(CTK_USE_GIT_PROTOCOL)
  361. set(git_protocol "git")
  362. if(NOT CTK_USE_GIT_PROTOCOL)
  363. set(git_protocol "http")
  364. endif()
  365. # Let's mark as advanced some default properties
  366. mark_as_advanced(CMAKE_INSTALL_PREFIX)
  367. mark_as_advanced(DART_TESTING_TIMEOUT)
  368. # KWStyle
  369. option(CTK_USE_KWSTYLE "Enable sourcecode-based style tests." OFF)
  370. mark_as_advanced(CTK_USE_KWSTYLE)
  371. # Qt Designer Plugins
  372. option(CTK_BUILD_QTDESIGNER_PLUGINS "Build Qt Designer plugins" ON)
  373. mark_as_advanced(CTK_BUILD_QTDESIGNER_PLUGINS)
  374. #-----------------------------------------------------------------------------
  375. # CTK Libraries
  376. #
  377. ctk_lib_option(Core
  378. "Build the Core library" ON)
  379. ctk_lib_option(PluginFramework
  380. "Build the Plugin Framework" OFF
  381. CTK_ENABLE_PluginFramework)
  382. ctk_lib_option(Widgets
  383. "Build the Widgets library" OFF
  384. CTK_ENABLE_Widgets OR (CTK_ENABLE_DICOMApplicationHosting AND CTK_BUILD_EXAMPLES) OR CTK_USE_QTTESTING)
  385. ctk_lib_option(DICOM/Core
  386. "Build the DICOM Core library" OFF
  387. CTK_ENABLE_DICOM OR (CTK_ENABLE_DICOMApplicationHosting AND CTK_BUILD_EXAMPLES))
  388. ctk_lib_option(DICOM/Widgets
  389. "Build the DICOM Widgets library" OFF
  390. CTK_ENABLE_DICOM AND CTK_ENABLE_Widgets OR (CTK_ENABLE_DICOMApplicationHosting AND CTK_BUILD_EXAMPLES))
  391. ctk_lib_option(ImageProcessing/ITK/Core
  392. "Build the ITK Core library" OFF)
  393. ctk_lib_option(Scripting/Python/Core
  394. "Build the Python Core library" OFF)
  395. ctk_lib_option(Scripting/Python/Widgets
  396. "Build the Python Widgets library" OFF
  397. CTK_LIB_Widgets AND CTK_ENABLE_Python_Wrapping)
  398. ctk_lib_option(Visualization/VTK/Core
  399. "Build the VTK Core library" OFF)
  400. ctk_lib_option(Visualization/VTK/Widgets
  401. "Build the VTK Widgets library" OFF)
  402. ctk_lib_option(CommandLineModules/Core
  403. "Build the Command Line Module core library" OFF)
  404. ctk_lib_option(CommandLineModules/Frontend/QtWebKit
  405. "Build the QtWebKit based Command Line Module front-end" OFF)
  406. ctk_lib_option(CommandLineModules/Frontend/QtGui
  407. "Build the QtGui based Command Line Module front-end" OFF)
  408. ctk_lib_option(CommandLineModules/Backend/LocalProcess
  409. "Build the Command Line Module back-end for local processes" OFF)
  410. ctk_lib_option(CommandLineModules/Backend/FunctionPointer
  411. "Build the Command Line Module back-end for function pointers" OFF)
  412. #ctk_lib_option(Visualization/XIP
  413. # "Build the XIP library" OFF)
  414. # Save the set of enabled libs in a cache file
  415. set(_enabled_libs)
  416. foreach(_lib ${CTK_LIBS})
  417. if(CTK_LIB_${_lib})
  418. list(APPEND _enabled_libs ${_lib})
  419. endif()
  420. endforeach()
  421. set(CTK_ENABLED_LIBS ${_enabled_libs} CACHE INTERNAL "" FORCE)
  422. #-----------------------------------------------------------------------------
  423. # CTK Applications - Use ON or OFF to indicate if the application should be built by default
  424. #
  425. ctk_app_option(ctkDICOM
  426. "Build the DICOM example application" OFF
  427. CTK_ENABLE_DICOM AND CTK_BUILD_EXAMPLES)
  428. ctk_app_option(ctkDICOMIndexer
  429. "Build the DICOM example application" OFF
  430. CTK_ENABLE_DICOM AND CTK_BUILD_EXAMPLES)
  431. ctk_app_option(ctkDICOMDemoSCU
  432. "Build the DICOM example application" OFF
  433. CTK_ENABLE_DICOM AND CTK_BUILD_EXAMPLES)
  434. ctk_app_option(ctkDICOMQuery
  435. "Build the DICOM example application" OFF
  436. CTK_ENABLE_DICOM AND CTK_BUILD_EXAMPLES)
  437. ctk_app_option(ctkDICOMRetrieve
  438. "Build the DICOM example application" OFF
  439. CTK_ENABLE_DICOM AND CTK_BUILD_EXAMPLES)
  440. ctk_app_option(ctkDICOMQueryRetrieve
  441. "Build the DICOM example application" OFF
  442. CTK_ENABLE_DICOM AND CTK_BUILD_EXAMPLES)
  443. ctk_app_option(ctkDICOMHost
  444. "Build the DICOM application host example application" OFF
  445. CTK_ENABLE_DICOMApplicationHosting AND CTK_BUILD_EXAMPLES)
  446. ctk_app_option(ctkExampleHost
  447. "Build the DICOM example application" OFF
  448. CTK_ENABLE_DICOMApplicationHosting AND CTK_BUILD_EXAMPLES)
  449. ctk_app_option(ctkExampleHostedApp
  450. "Build the DICOM example application" OFF
  451. CTK_ENABLE_DICOMApplicationHosting AND CTK_BUILD_EXAMPLES)
  452. ctk_app_option(ctkEventBusDemo
  453. "Build the DICOM example application" OFF
  454. CTK_ENABLE_PluginFramework AND CTK_BUILD_EXAMPLES)
  455. ctk_app_option(ctkCommandLineModuleExplorer
  456. "Build the Command Line Module Explorer" OFF
  457. CTK_BUILD_EXAMPLES)
  458. # We use the CTKWidgets library together with the Qt Designer plug-in
  459. # in ctkCommandLineModuleExplorer, so enabling the options here.
  460. # (We do not need to link them into the executable, hence no entries
  461. # in target_libraries.cmake)
  462. if(CTK_APP_ctkCommandLineModuleExplorer)
  463. foreach(_option CTK_BUILD_QTDESIGNER_PLUGINS)
  464. if(NOT ${_option})
  465. get_property(_docstring CACHE ${_option} PROPERTY HELPSTRING)
  466. set(${_option} ON CACHE BOOL "${_docstring}" FORCE)
  467. message("Enabling option [${_option}] required by [ctkCommandLineModuleExplorer]")
  468. endif()
  469. endforeach()
  470. endif()
  471. ctk_app_option(ctkPluginBrowser
  472. "Build the DICOM example application" OFF
  473. CTK_ENABLE_PluginFramework AND CTK_BUILD_EXAMPLES)
  474. ctk_app_option(ctkPluginGenerator
  475. "Build the DICOM example application" OFF
  476. CTK_ENABLE_PluginFramework AND CTK_BUILD_EXAMPLES)
  477. ctk_app_option(ctkDICOMObjectViewer
  478. "Build the DICOM example application" OFF
  479. CTK_ENABLE_DICOM AND CTK_BUILD_EXAMPLES)
  480. ctk_app_option(ctkSimplePythonShell
  481. "Build the DICOM example application" OFF
  482. CTK_ENABLE_Python_Wrapping AND CTK_BUILD_EXAMPLES)
  483. if(CTK_USE_QTTESTING)
  484. ctk_app_option(ctkQtTesting
  485. "Build the ctkQtTesting example application" OFF
  486. CTK_BUILD_EXAMPLES)
  487. endif()
  488. # Save the set of enabled apps in a cache file
  489. set(_enabled_apps)
  490. foreach(_app ${CTK_APPS})
  491. if(CTK_APP_${_app})
  492. list(APPEND _enabled_apps ${_app})
  493. endif()
  494. endforeach()
  495. set(CTK_ENABLED_APPS ${_enabled_apps} CACHE INTERNAL "" FORCE)
  496. #-----------------------------------------------------------------------------
  497. # CTK Plugins - none of them is build by default
  498. #
  499. # Plugins in the list below are not build by default
  500. set(plugin_list
  501. # Optional plug-ins implementings interfaces in PluginFramework/service/
  502. org.commontk.configadmin
  503. org.commontk.eventadmin
  504. org.commontk.log
  505. org.commontk.log4qt
  506. org.commontk.metatype
  507. )
  508. foreach(_plugin ${plugin_list})
  509. ctk_plugin_option(${_plugin} "Build the ${_plugin} plugin." OFF)
  510. endforeach()
  511. # Plug-ins related to the PluginGenerator application
  512. ctk_plugin_option(org.commontk.plugingenerator.core "Build the org.commontk.plugingenerator.core plugin." OFF)
  513. ctk_plugin_option(org.commontk.plugingenerator.ui
  514. "Build the org.commontk.plugingenerator.ui plugin." OFF
  515. CTK_APP_ctkPluginGenerator)
  516. # Plug-ins related to DICOM WG23 (Application Hosting)
  517. ctk_plugin_option(org.commontk.dah.core "Build the org.commontk.dah.core plugin." OFF)
  518. ctk_plugin_option(org.commontk.dah.hostedapp "Build the org.commontk.dah.hostedapp plugin." OFF
  519. CTK_ENABLE_DICOMApplicationHosting)
  520. ctk_plugin_option(org.commontk.dah.host "Build the org.commontk.dah.host plugin." OFF
  521. CTK_ENABLE_DICOMApplicationHosting)
  522. ctk_plugin_option(org.commontk.dah.exampleapp
  523. "Build the org.commontk.dah.exampleapp plugin." OFF
  524. CTK_APP_ctkExampleHostedApp)
  525. ctk_plugin_option(org.commontk.dah.cmdlinemoduleapp
  526. "Build the org.commontk.dah.cmdlinemoduleapp plugin." OFF
  527. CTK_APP_ctkCommandLineModuleApp)
  528. ctk_plugin_option(org.commontk.dah.examplehost
  529. "Build the org.commontk.dah.examplehost plugin." OFF
  530. CTK_APP_ctkExampleHost)
  531. # Plug-ins related to the EventBus demo application
  532. ctk_plugin_option(org.commontk.eventbus
  533. "Build the org.commontk.eventbus plugin." OFF
  534. CTK_APP_ctkEventBusDemo)
  535. # Add the PluginsContrib repo to the build system
  536. option(CTK_USE_CONTRIBUTED_PLUGINS OFF "Use CTK plug-ins from the PluginsContrib repository")
  537. mark_as_advanced(CTK_USE_CONTRIBUTED_PLUGINS)
  538. if(CTK_USE_CONTRIBUTED_PLUGINS)
  539. ctkFunctionAddPluginRepo(NAME PluginsContrib
  540. GIT_URL github.com/commontk/PluginsContrib.git
  541. GIT_TAG 7fc37f400c
  542. )
  543. endif()
  544. #-----------------------------------------------------------------------------
  545. # Generate target_directories list - List of directory corresponding to the different
  546. # libraries, plugins and applications associated with the corresponding option name.
  547. #
  548. # The following FOREACH loops are used to:
  549. # 1) Update either CTK_LIBS_SUBDIRS, CTK_PLUGINS_SUBDIRS or CTK_APPS_SUBDIRS variables
  550. #
  551. # For CTK libraries, if the file Libs/<DIR>/<LIBNAME>/ctk_library_options.cmake exists,
  552. # in addition to 'CTK_LIB_<DIR>/<LIBNAME>' option, the following ones
  553. # will also be available in CMake configure menu:
  554. # CTK_LIB_<DIR>/<LIBNAME>_OPT1 (set to OFF)
  555. # CTK_LIB_<DIR>/<LIBNAME>_OPT2 (set to ON)
  556. #
  557. # The file Libs/<DIR>/<LIBNAME>/ctk_library_options.cmake should look like:
  558. #
  559. # set(ctk_library_options
  560. # OPT1:OFF
  561. # OPT2:ON
  562. # )
  563. # Create list of directories corresponding to the enabled targets
  564. set(target_directories)
  565. set(ctk_lib_options_list) # This list will be updated in ctkMacroAddCtkLibraryOptions
  566. foreach(lib ${CTK_LIBS})
  567. if(CTK_LIB_${lib})
  568. ctkMacroAddCtkLibraryOptions(${lib})
  569. endif()
  570. list(APPEND target_directories "${CMAKE_CURRENT_SOURCE_DIR}/Libs/${lib}^^CTK_LIB_${lib}")
  571. endforeach()
  572. foreach(plugin ${CTK_PLUGINS})
  573. if(${plugin}_SOURCE_DIR)
  574. list(APPEND target_directories "${${plugin}_SOURCE_DIR}^^CTK_PLUGIN_${plugin}")
  575. else()
  576. list(APPEND target_directories "${CMAKE_CURRENT_SOURCE_DIR}/Plugins/${plugin}^^CTK_PLUGIN_${plugin}")
  577. endif()
  578. endforeach()
  579. foreach(app ${CTK_APPS})
  580. list(APPEND target_directories "${CMAKE_CURRENT_SOURCE_DIR}/Applications/${app}^^CTK_APP_${app}")
  581. endforeach()
  582. #message(STATUS target_directories:${target_directories})
  583. #-----------------------------------------------------------------------------
  584. # Compile DGraph - An application allowing to check for cycle in DAG and also obtain the
  585. # topological order.
  586. try_compile(RESULT_VAR ${CTK_BINARY_DIR}/Utilities/DGraph ${CTK_SOURCE_DIR}/Utilities/DGraph
  587. DGraph
  588. CMAKE_FLAGS
  589. -DCMAKE_OSX_ARCHITECTURES:STRING=${CMAKE_OSX_ARCHITECTURES}
  590. -DCMAKE_OSX_DEPLOYMENT_TARGET:STRING=${CMAKE_OSX_DEPLOYMENT_TARGET}
  591. -DCMAKE_OSX_SYSROOT:STRING=${CMAKE_OSX_SYSROOT}
  592. -DCMAKE_VERBOSE_MAKEFILE:BOOL=FALSE
  593. OUTPUT_VARIABLE output)
  594. if(NOT RESULT_VAR)
  595. message(FATAL_ERROR "Failed to compile DGraph application.\n${output}")
  596. endif()
  597. find_program(DGraph_EXECUTABLE DGraph
  598. "${CTK_BINARY_DIR}/Utilities/DGraph/"
  599. "${CTK_BINARY_DIR}/Utilities/DGraph/bin/"
  600. "${CTK_BINARY_DIR}/Utilities/DGraph/Debug/"
  601. "${CTK_BINARY_DIR}/Utilities/DGraph/Release/")
  602. mark_as_advanced(DGraph_EXECUTABLE)
  603. #-----------------------------------------------------------------------------
  604. # Let's make sure the enabled/disabled libraries, plugins or applications are coherent
  605. #
  606. ctkFunctionGenerateDGraphInput(${CTK_BINARY_DIR} "${target_directories}")
  607. ctkFunctionGenerateDGraphInput(${CTK_BINARY_DIR} "${target_directories}" WITH_EXTERNALS)
  608. ctkMacroValidateBuildOptions("${CTK_BINARY_DIR}" "${DGraph_EXECUTABLE}" "${target_directories}")
  609. #-----------------------------------------------------------------------------
  610. # CTK Python wrapping
  611. # Enable CTK_LIB_Scripting/Python/Core if either CTK_ENABLE_Python_Wrapping OR CTK_WRAP_PYTHONQT_FULL
  612. #
  613. set(CTK_WRAP_PYTHONQT_LIGHT ${CTK_ENABLE_Python_Wrapping})
  614. option(CTK_WRAP_PYTHONQT_FULL "Experimental - Wrap CTK classes using Qt meta-object system into Python language" OFF)
  615. mark_as_advanced(CTK_WRAP_PYTHONQT_FULL)
  616. if(CTK_WRAP_PYTHONQT_FULL AND CTK_WRAP_PYTHONQT_LIGHT)
  617. message(FATAL_ERROR "CTK_ENABLE_Python_Wrapping AND CTK_WRAP_PYTHONQT_FULL options are mutually exclusive. Please enable only one !")
  618. endif()
  619. set(logical_expr CTK_WRAP_PYTHONQT_LIGHT OR CTK_WRAP_PYTHONQT_FULL)
  620. if((${logical_expr}) AND NOT CTK_LIB_Scripting/Python/Core)
  621. set(CTK_LIB_Scripting/Python/Core ON CACHE BOOL "Build the Python Core library" FORCE)
  622. set(enabling_msg)
  623. ctk_option_logical_expression_to_message(enabling_msg "${logical_expr}")
  624. message("Enabling [CTK_LIB_Scripting/Python/Core] because of [${enabling_msg}] evaluates to True")
  625. endif()
  626. set(logical_expr CTK_LIB_Scripting/Python/Core AND CTK_LIB_Scripting/Python/Core_PYTHONQT_USE_VTK)
  627. if(${logical_expr} AND NOT CTK_LIB_Visualization/VTK/Core)
  628. set(CTK_LIB_Visualization/VTK/Core ON CACHE BOOL "Build the VTK Core library" FORCE)
  629. set(enabling_msg)
  630. ctk_option_logical_expression_to_message(enabling_msg "${logical_expr}")
  631. message("Enabling [CTK_LIB_Visualization/VTK/Core] because of [${enabling_msg}] evaluates to True")
  632. endif()
  633. # Check if dependencies are satisfied
  634. if(CTK_LIB_Scripting/Python/Core)
  635. find_package(PythonInterp)
  636. if(NOT PYTHONINTERP_FOUND)
  637. message(FATAL_ERROR "PYTHON_EXECUTABLE variable should be set to build CTK_LIB_Scripting/Python")
  638. endif()
  639. find_package(PythonLibs)
  640. if(NOT PYTHONLIBS_FOUND)
  641. message(FATAL_ERROR "PYTHON_LIBRARIES and PYTHON_INCLUDE_DIRS should be set to build CTK_LIB_Scripting/Python")
  642. endif()
  643. endif()
  644. #-----------------------------------------------------------------------------
  645. # DGraph
  646. #
  647. # Generate DGraph input file expected by DGraph
  648. ctkFunctionGenerateDGraphInput(${CTK_BINARY_DIR} "${target_directories}" WITH_OPTION)
  649. # Obtain list of target ordered topologically
  650. ctkMacroSetPaths("${QT_INSTALLED_LIBRARY_DIR}")
  651. execute_process(
  652. COMMAND "${DGraph_EXECUTABLE}" "${CTK_BINARY_DIR}/DGraphInput.txt"
  653. WORKING_DIRECTORY ${CTK_BINARY_DIR}
  654. RESULT_VARIABLE RESULT_VAR
  655. OUTPUT_VARIABLE CTEST_PROJECT_SUBPROJECTS_OUTPUT
  656. ERROR_VARIABLE error
  657. OUTPUT_STRIP_TRAILING_WHITESPACE
  658. )
  659. if(RESULT_VAR)
  660. message(FATAL_ERROR "Failed to obtain list of target ordered topologically.\n${RESULT_VAR}\n${CTK_BINARY_DIR}\n${error}")
  661. endif()
  662. # Convert 'CTEST_PROJECT_SUBPROJECTS_OUTPUT' to a list
  663. string(REPLACE " " "\\;" CTEST_PROJECT_SUBPROJECTS "${CTEST_PROJECT_SUBPROJECTS_OUTPUT}")
  664. set(CTEST_PROJECT_SUBPROJECTS ${CTEST_PROJECT_SUBPROJECTS})
  665. # If the list of subproject is empty, let's at least build CTKCore
  666. list(LENGTH CTEST_PROJECT_SUBPROJECTS subproject_count)
  667. IF (subproject_count EQUAL 0)
  668. set(CTEST_PROJECT_SUBPROJECTS CTKCore)
  669. endif()
  670. # Configure CTestConfigSubProject.cmake that could be used by CTest scripts
  671. configure_file(${CTK_SOURCE_DIR}/CMake/CTestConfigSubProject.cmake.in
  672. ${CTK_BINARY_DIR}/CTestConfigSubProject.cmake)
  673. #-----------------------------------------------------------------------------
  674. # Project.xml
  675. #
  676. # Generate Project.xml file expected by the CTest driver script
  677. ctkFunctionGenerateProjectXml(${CTK_BINARY_DIR} ${PROJECT_NAME} "${target_directories}" ${CTK_SUPERBUILD})
  678. #-----------------------------------------------------------------------------
  679. # CTK dependencies - Projects should be TOPOLOGICALLY ordered
  680. #-----------------------------------------------------------------------------
  681. set(CTK_POSSIBLE_DEPENDENCIES
  682. CTKData
  683. QtTesting
  684. Log4Qt
  685. KWStyle
  686. VTK
  687. PythonQt
  688. PythonQtGenerator # Should be added after PythonQt - See comment in CMakeExternals/PythonQtGenerator.cmake
  689. DCMTK
  690. ZMQ
  691. QtSOAP
  692. qxmlrpc
  693. OpenIGTLink
  694. XIP
  695. ITK
  696. )
  697. #-----------------------------------------------------------------------------
  698. # Check out the ExternalProjectsContrib repository
  699. if(CTK_USE_CONTRIBUTED_PLUGINS)
  700. if(CTK_SUPERBUILD)
  701. ctkFunctionCheckoutRepo(
  702. NAME ExternalProjectsContrib
  703. GIT_URL github.com/commontk/ExternalProjectsContrib.git
  704. GIT_TAG c15781914f
  705. )
  706. endif()
  707. file(GLOB _contrib_scripts ${ExternalProjectsContrib_DIR}/*.cmake)
  708. foreach(_contrib_script ${_contrib_scripts})
  709. get_filename_component(_script_name ${_contrib_script} NAME_WE)
  710. list(APPEND CTK_POSSIBLE_DEPENDENCIES ${_script_name})
  711. set(${_script_name}_FILEPATH ${_contrib_script})
  712. endforeach()
  713. endif()
  714. set(CTK_DEPENDENCIES) # This variable will contain the list of required CTK dependencies
  715. include(CMake/ctkBlockCheckDependencies.cmake)
  716. #-----------------------------------------------------------------------------
  717. # Superbuild script
  718. #
  719. if(CTK_SUPERBUILD)
  720. include("${CMAKE_CURRENT_SOURCE_DIR}/SuperBuild.cmake")
  721. return()
  722. endif()
  723. #-----------------------------------------------------------------------------
  724. # Expand variables containing include and library directories for external projects
  725. # This relies on the variable EXTERNAL_TARGETS set in ctkMacroValidateBuildOptions
  726. foreach(_external_target ${EXTERNAL_TARGETS})
  727. if(${_external_target}_FIND_PACKAGE_CMD)
  728. #message("Calling find_package(${${_external_target}_FIND_PACKAGE_CMD})")
  729. find_package(${${_external_target}_FIND_PACKAGE_CMD} REQUIRED)
  730. endif()
  731. endforeach()
  732. foreach(_external_target ${EXTERNAL_TARGETS})
  733. if(${_external_target}_INCLUDE_DIRS)
  734. #message("[${_external_target}] Resolving include variables: ${${_external_target}_INCLUDE_DIRS}")
  735. foreach(_include_variable ${${_external_target}_INCLUDE_DIRS})
  736. #message("[${_external_target}] Appending ${${_include_variable}}")
  737. if(${_include_variable})
  738. list(APPEND ${_external_target}_INCLUDE_DIRS ${${_include_variable}})
  739. else()
  740. list(APPEND ${_external_target}_INCLUDE_DIRS ${_include_variable})
  741. endif()
  742. #message("[${_external_target}] New dirs: ${${_external_target}_INCLUDE_DIRS}")
  743. endforeach()
  744. #message("[${_external_target}] Appended dirs: ${${_external_target}_INCLUDE_DIRS}")
  745. endif()
  746. if(${_external_target}_LIBRARY_DIRS)
  747. #message("[${_external_target}] Resolving library variables: ${${_external_target}_LIBRARY_DIRS}")
  748. foreach(_library_variable ${${_external_target}_LIBRARY_DIRS})
  749. #message("[${_external_target}] Appending ${${_library_variable}}")
  750. if(${_library_variable})
  751. list(APPEND ${_external_target}_LIBRARY_DIRS ${${_library_variable}})
  752. else()
  753. list(APPEND ${_external_target}_LIBRARY_DIRS ${_library_variable})
  754. endif()
  755. #message("[${_external_target}] New dirs: ${${_external_target}_LIBRARY_DIRS}")
  756. endforeach()
  757. #message("[${_external_target}] Appended dirs: ${${_external_target}_LIBRARY_DIRS}")
  758. endif()
  759. endforeach()
  760. set(CTK_WRAP_PYTHONQT_USE_VTK ${CTK_LIB_Scripting/Python/Core_PYTHONQT_USE_VTK})
  761. #-----------------------------------------------------------------------------
  762. # CTK_SUPERBUILD_BINARY_DIR
  763. # If CTK_SUPERBUILD_BINARY_DIR isn't defined, it means CTK is *NOT* build using Superbuild.
  764. # In that specific case, CTK_SUPERBUILD_BINARY_DIR should default to CTK_BINARY_DIR
  765. if(NOT DEFINED CTK_SUPERBUILD_BINARY_DIR)
  766. set(CTK_SUPERBUILD_BINARY_DIR ${CTK_BINARY_DIR})
  767. endif()
  768. #-----------------------------------------------------------------------------
  769. # Configure files with settings
  770. #
  771. configure_file(${CTK_SOURCE_DIR}/CMake/UseCTK.cmake.in
  772. ${CTK_SUPERBUILD_BINARY_DIR}/UseCTK.cmake COPYONLY IMMEDIATE)
  773. set(CTK_CONFIG_H_INCLUDE_DIR ${CTK_BINARY_DIR})
  774. #-----------------------------------------------------------------------------
  775. # Set C/CXX Flags
  776. #
  777. set(CMAKE_CXX_FLAGS ${CTK_CXX_FLAGS} CACHE STRING "CMake C Flags" FORCE)
  778. set(CMAKE_C_FLAGS ${CTK_C_FLAGS} CACHE STRING "CMake CXX Flags" FORCE)
  779. #-----------------------------------------------------------------------------
  780. # Set the header template which defines custom export/import macros
  781. # for shared libraries
  782. #
  783. set(CTK_EXPORT_HEADER_TEMPLATE "${CTK_SOURCE_DIR}/Libs/ctkExport.h.in")
  784. #-----------------------------------------------------------------------------
  785. # Setup testing environment before Libs are added
  786. #
  787. add_subdirectory(Libs/Testing)
  788. #-----------------------------------------------------------------------------
  789. # Add CTK library subdirectories
  790. #
  791. foreach(lib ${CTK_LIBS})
  792. if(CTK_LIB_${lib})
  793. add_subdirectory(Libs/${lib})
  794. endif()
  795. # Always add the Documentation sub-directory for additional processing
  796. if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/Libs/${lib}/Documentation/CMakeLists.txt)
  797. add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/Libs/${lib}/Documentation)
  798. endif()
  799. endforeach()
  800. # Add the CommandLineModules root directory for additional processing
  801. add_subdirectory(Libs/CommandLineModules)
  802. #-----------------------------------------------------------------------------
  803. if(CTK_USE_QTTESTING)
  804. add_subdirectory(Libs/QtTesting)
  805. endif()
  806. #-----------------------------------------------------------------------------
  807. # Add CTK plugin subdirectories
  808. #
  809. foreach(plugin ${CTK_PLUGINS})
  810. if(CTK_PLUGIN_${plugin})
  811. if(${plugin}_SOURCE_DIR)
  812. add_subdirectory(${${plugin}_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR}/Plugins/${plugin})
  813. else()
  814. add_subdirectory(Plugins/${plugin})
  815. endif()
  816. endif()
  817. endforeach()
  818. #-----------------------------------------------------------------------------
  819. # Add CTK application subdirectories
  820. #
  821. foreach(app ${CTK_APPS})
  822. IF (CTK_APP_${app})
  823. add_subdirectory(Applications/${app})
  824. endif()
  825. endforeach()
  826. if(BUILD_TESTING)
  827. add_subdirectory(Applications/Testing)
  828. endif()
  829. #-----------------------------------------------------------------------------
  830. # Add general purpose subdirectories
  831. #
  832. #add_subdirectory(Testing)
  833. #add_subdirectory(Examples)
  834. #-----------------------------------------------------------------------------
  835. # Style Checking configuration
  836. #
  837. include(Utilities/KWStyle/KWStyle.cmake)
  838. #---------------------------------------------------------------------------
  839. # Documentation
  840. #
  841. add_subdirectory( Documentation )
  842. #-----------------------------------------------------------------------------
  843. # The commands in this directory are intended to be executed as
  844. # the end of the whole configuration process, as a "last step".
  845. # This directory is typically the last SUBDIRS in the main CMakeLists.txt.
  846. add_subdirectory(CMake/LastConfigureStep)